Se nos plantea el siguiente problema.
Determina la ecuación de la recta secante a las rectas de ecuaciones \[ r: \left\{ \begin{array}{cl} x & = 2+t \\ y & = 1 \\ z & = t-1 \end{array} \right. ; t \in \mathbb{R}, \] y \[ s: \frac{x-2}{2} = y-5 = z-2, \] sabiendo que pasa por el punto \(A(0,0,1)\).
La estrategia que vamos a seguir es la de calcular los planos que contienen a cada una de las rectas y al punto A. Ambos planos formarán las ecuaciones cartesianas de la recta pedida.
Guardamos en una variable las coordenadas del punto A,
A: [0,0,1]$
De la ecuación paramétrica que define r obtenemos un punto por el que pasa y un vector de dirección,
P1: [2,1,-1]$ v1: [1,0,1]$
El primer plano que buscamos contiene a A y tiene como uno de sus vectores de dirección el de la propia recta; como segundo vector podemos tomar \(\vec{P_1 A}\), con lo que la ecuación del plano será
P1A: A - P1$ plano1: expand(determinant(matrix([x,y,z]-P1, v1, P1A)))=0;
\[ -z-4\,y+x+1=0 \]
Acabamos de calcular \[ \begin{vmatrix} x-2 & y-1 & z+1 \\ 1 & 0 & 1 \\ -2 & -1 & 2 \end{vmatrix} = -z-4\,y+x+1=0. \]
Por otro lado, de la ecuación continua que defiene s también obtenemos punto y vector,
P2: [2,5,2] $ v2: [2,1,1]$
El plano que contiene a esta recta y al punto A es
P2A: A - P2$ plano2: expand(determinant(matrix([x,y,z]-P2, v2, P2A)))=0;
\[ -8\,z+4\,x+8=0 \]
Es decir, \[ \begin{vmatrix} x-2 & y-5 & z-2 \\ 2 & 1 & 1 \\ -2 & -5 & -1 \end{vmatrix} = -8\,z+4\,x+8=0. \]
Como conclusión de todo lo anterior, la recta pedida tiene las ecuaciones cartesianas dadas por
[plano1, plano2];
\[ \left[ -z-4\,y+x+1=0 , -8\,z+4\,x+8=0 \right] \]
Veamos el aspecto que tiene todo este asunto:
load(draw)$
draw_renderer = vtk$
draw3d(
terminal = vrml,
/* primera recta */
line_type = tube,
line_width = 0.3,
parametric(2+t, 1, t-1, t,-10,10),
/* segunda recta */
parametric(2+2*t, t+5, t+2, t,-7,5),
/* punto */
point_type = sphere,
color = yellow,
points([[0,0,1]]),
/* primer plano */
color = red,
implicit(x-4*y-z+1=0,x,-10,10,y,-10,10,z,-10,10),
/* segundo plano */
color = green,
implicit(x-2*z+2=0,x,-10,10,y,-10,10,z,-10,10) );
Arrastra el ratón para mover la escena.
Las dos rectas azules y el punto amarillo son los datos que nos da el enunciado. Los planos rojo y verde son los que hemos calculado. La intersección de los planos es la recta que pasa por el punto y es secantes a las recta dadas.
© 2018, TecnoStats.